Microchip Taiwan - Re: 請教.一直解決不了的問題. [8-bit PIC® MCU]

:::

論壇索引

Board index » 產品技術問題 (開版時請註明使用的元件編號及C編譯器版本) » » 8-bit PIC® MCU » 請教.一直解決不了的問題.

Browsing this Thread: 1 Anonymous Users

底部

前一個主題

下一個主題登入發表文章

quantum

Re: 請教.一直解決不了的問題.

新會員

哈哈.你一說我也注意到了.
謝謝你啦.
過一陣子我也要去上一下教育訓練.
希望到時候懂的會多一點.
再次感謝你啦.^^.真開心.

發表於: 2006/11/2 13:31

Blake

Re: 請教.一直解決不了的問題.

高級會員

MOVWF TRISD
;
BANKSEL TRISD //??? BANKSEL PORTD?
; MOVLW 0
;
BSF INTCON,T0IE
BSF INTCON,GIE

BANK 沒切回來??

發表於: 2006/11/2 12:15

quantum

Re: 請教.一直解決不了的問題.

新會員

哇~你真的是個大好人.好快的時間就幫我解決問題了.
真是聽君一昔話.勝拼二星期試誤.
我把watchdog關掉後果然會亮十次了.
晚點我再把相關的資料看清楚.謝謝你啦.
另外.能不能夠再請教另一個問題.
就是有關於Timer0的問題.
我根據書上寫的範例.想要拿來練習.無奈我怎麼試它都不動.
我是想利用Timer0來精確計時.並依序點亮LED.
========以下是程式碼==========
;


;    LCD + PRECISION TIMER (00.00~99.99 SEC) (Timer0)

;

    LIST P=16F877A, R=DEC

    #INCLUDE P16F877A.INC

    CBLOCK 0X20

    ENDC

;

;    define RAM

;

    CBLOCK

     R0_PRC100mS

     W_BAK, STATUS_BAK        ; back up RAM for w register

    ENDC

;

;    define data

;

DATMR0    EQU 256-125             ; 125*16uS=2mS(for 16 MHz)

;

;

;.......................................................................

;

    ORG 0

    NOP

    GOTO MAIN        ; reset vector

;

    ORG 4            ; 

    MOVWF W_BAK        ; save w register

    SWAPF STATUS,W        ; save STATUS register

    MOVWF STATUS_BAK



    MOVLW DATMR0        ; 

    ADDWF TMR0,F        ; restore TMR0



    DECF R0_PRC100mS,F



    BCF INTCON,T0IF        ; clear interrupt flag

    SWAPF STATUS_BAK,W

    MOVWF STATUS

    SWAPF W_BAK,F

    SWAPF W_BAK,W        ; restore w register without affecting status

    RETFIE            ; return + (bsf INTCON,GIE)

;

;................................

;

MAIN:

;

    BANKSEL OPTION_REG    ; OPTION_REG is in bank1

    MOVLW B'00000101'    ; RBPU(0),INTEDG(0),T0CS(0=INT),T0SE(0)

                ; PSA(0=PRESC to timer)

                ; PS2~0(101=1/64)

    MOVWF OPTION_REG

    BANKSEL TMR0

    MOVLW DATMR0        ; 64*125=2000uS for 16 MHz crystal

    MOVWF TMR0        ; reset buffer of timer0

    MOVLW 50        ; 50*2mS=100mS

    MOVWF R0_PRC100mS    ; reset 50*2mS counter

;

    BANKSEL    TRISD    

    MOVLW    0

    MOVWF    TRISD

;

    BANKSEL TRISD

;    MOVLW    0

;

    BSF INTCON,T0IE        ; actuate timer0 interrupt

    BSF INTCON,GIE        ; actuate global interrupt

;

;

MAIN1:

    CLRF    PORTD    

    CALL PRC_100mS        ; precission 100 mS timer

;

    BSF  PORTD,0

    CALL PRC_100mS

;

    BSF  PORTD,1

    CALL PRC_100mS

;

    BSF  PORTD,2

    CALL PRC_100mS

;

    BSF  PORTD,3

    CALL PRC_100mS    

;

    GOTO MAIN1

;

;

;.............................................................................

;

;    precission 100mS timer

;

PRC_100mS:

    TSTF R0_PRC100mS

    SKPZ

    GOTO PRC_100mS

;

    MOVLW 50

    MOVWF R0_PRC100mS        ; restore 50*2 mS counter

;

    RETURN

;

;

;---------------------------------------------------------------;

;

    END

========以上是程式碼==========
因為有上次的經驗.所以我有把watchdog給disable掉.
不過還是一樣沒有任何反應.
希望有人可以教教小弟我.
PS.這個地方真好.希望哪天我也可以成為教人的那位.^^.

發表於: 2006/11/2 11:27

Blake

Re: 請教.一直解決不了的問題.

高級會員

Watchdog -> Enabled
但是沒看到有clrwdt的指令?
會不會是watchdog重置cup造成的

發表於: 2006/11/2 10:57

quantum

請教.一直解決不了的問題.

新會員

前一陣子才開始學PIC.
晶片是16f877a.
我是想做出一個燈亮一次.另一個燈亮十次的效果.
可是我怎麼用另一個燈都只亮二次.
有沒人可以幫我一下.看看我的東西到底哪裡有問題.
拜託一下了.我被困擾好久了.=.=
========以下是程式碼==========
LIST P=16F877A, R=DEC;
INCLUDE <P16F877A.INC>

CBLOCK H'20'
ENDC
;
CBLOCK
STEPNUM
ENDC
;
ORG 0
NOP

BANKSEL TRISD
MOVLW B'11100000'
MOVWF TRISD
BANKSEL PORTD

; BCF USRFLAG,DRCT

MOVLW 10
MOVWF STEPNUM

AGAIN:
MOVLW B'11100000'
MOVWF PORTD

BSF PORTD,0
CALL D100mS

BCF PORTD,0
CALL D100mS

MOVLW 10
MOVWF STEPNUM

AGAIN1:
BSF PORTD,1
CALL D100mS

BCF PORTD,1
CALL D100mS

DECFSZ STEPNUM,F
GOTO AGAIN1

GOTO AGAIN
;

CBLOCK
R0_D100mS
R1_D100mS, R2_D100mS
ENDC
;
D100mS:
MOVLW 10
MOVWF R0_D100mS
D100mS1:
MOVLW 100
MOVWF R1_D100mS
D100mS2:
MOVLW 100
MOVWF R2_D100mS
D100mS3:
NOP
DECFSZ R2_D100mS,F
GOTO D100mS3
DECFSZ R1_D100mS,F
GOTO D100mS2
DECFSZ R0_D100mS,F
GOTO D100mS1
RETURN
;
;
END
========以上是程式碼==========
Device,Config的設定.
Watchdog -> Enabled
Brown-Out Reset Enable -> Enabled
Low Voltage Programming -> Enabled
其餘都是off mode.

請大家幫個忙.教一下小弟吧.謝謝.

發表於: 2006/11/2 10:33