笨鴨的示波器是.. LG OS-5100RA ..
在阿美這兒修理太貴啦! 超過示波器一半的價碼 !
笨鴨的想法是... 利用回台北休假, 提回去修理;
不知道個位大鍋, 是否知道那兒可以修理 ???
價錢合理又修理技術好, 而且可以信賴的公司呢 ?
3Q , 3Q ,lor.

果然發生了
原來不只是我會出錯

我當初掛掉的是 Tektronix TDS 320
買進來的時候是8萬多的台幣(10幾年前)
原廠說修理要2萬多，而且之後也沒有提供保固及維修
因為已經停產

只好換了一台新的 TDS 2012 ，花了3萬多

不是膽大包天... 是笨的實在是可以囉 !!!
沒想太多, 就給它插上電啦....
Well ,,只不過是免費新造型燙髮 ,沒啥大不了啦.
Hahaha .....

Haha...沒錯, 我新買的壹台示波器就這樣掛啦!
也沒全掛啦 ! 死了一半,, 4 CH 變成 2Ch.
而且無法同步 , 波形穩定不來 ..只好眼睛想法子跟它同步啦!
所以趕緊買了一個 110V/110V 絕緣變壓器,
把所有儀表全隔離啦!
其實也沒啥事發生, 只不過是... 霹靂趴啦一聲...
弄得滿屋子煙, 火警警報也響起來, 老妹嚇的哇哇叫;
狗兒也嚇的頭也不回的跑到後院去啦....
哈.. 哈 ..產品不都是這樣產生的嘛 !!!

其實也還好，市面上很多產品也是直接用電容偶合ac電壓
省一個變壓器
測試的時候，人電到也還無所謂，感受一下 AC POWER的威力

唯一要注意的是 測試儀表，尤其是有接地3PIN的AC輸入
我曾經不小心沒注意到 AC的LN，地線一夾上去，就把示波器給掛了
後來只要是這種線路，我都會把儀表的電源線GND端拿掉

不要輕易嘗試我的錯誤，一損失是好幾萬
想像一下在信號輸入的GND跟接大地的POWER GND 之間 接上 AC 110會發生啥情形就好

大膽！

這樣的電路設計，測試時要小心呦

Dear All :
笨鴨閒來無事 ,手癢把家門口的自動照明燈拆開修改;
而且寫了個程式讓它聰明些....(聰明一些些而已 )
程式也許笨了些, 會工作呦 !! 有給它成就感多多.. 哈.. 哈..
希望各位大鍋,大姐兒, 看看有甚麼地方還可以修改的...3Q.

; PIC12F508 PIR+DIMMER+ZCD 06-14-2006
#include <p12F508.inc> ; processor specific variables
; Configure: Controls the reset pin, code protect, oscillator selection, WDT.
__CONFIG _MCLRE_OFF & _CP_OFF & _WDT_OFF &_IntRC_OSC
;-----[Defines & Variable Assignments]---------------------------------------
cblock 0x08 ; GP2=ZVS,GP5=TRIAC,GP3=SW1,GP4=PIR,GP1=SW2, GP0=MODE1-2
count ; count buffer
count1 ; count buffer
count2 ; count buffer
count3 ; total delay buffer
count4 ; max delay buffer
count5 ; loop buffer
endc
;-----[Reset Vector]---------------------------------------------------------
ORG 0x000 ; PIC goes here (Origin of code) after reset.
movwf OSCCAL ; Load the oscillator calibration factor.
movlw b'00000111' ; wake on pion change,pull-ups resister,max pre-scaler
OPTION ;
movlw b'00011111' ; Set GP0,1,2,3,4,, to an input, GPIO pins ,5 to outputs.
TRIS GPIO ; Register 06h
goto init
;-----------------------------[Sub routine]-----------------------------------
dly_100us
movlw d'33'
movwf count
keep
decfsz count,f
goto keep
retlw 0
step_up
call dly_100us
decfsz count3 ;
goto step_up ;
retlw 0
step_down
call dly_100us ;
incfsz count3 ;
goto step_down ;
retlw 0

;-----[Main routine]---------------------------------------------------------
init
btfsc GPIO,0 ; Mode A or Mode B
goto mode_A
goto hold ; mode B
mode_A
btfsc GPIO,4 ; PIR ready yet ??????
goto mode_A ; no
goto up
hold ;---------------- Minimum power routine.-------------------
btfss GPIO,4 ; Check PIR Yes= H = SET.
goto up ; Go up routine .
btfsc GPIO,2 ; Zero Voltage crossing yet ?8.26ms for half cycle.
goto H ; H cycle.
goto L ; L cycle.
H
btfsc GPIO,2 ; Zero Voltage crossing yet ?
goto H ;
goto triac ;
L
btfss GPIO,2 ; Zero Voltage crossing yet ?
goto L ;
goto triac ;
triac
movlw d'45' ; 5ms total delay.
movwf count3 ;
call step_up ; 100us per step up to increase light.
bsf GPIO,5 ; Set GP5 to trigger Triac .
call dly_100us ; Trigger width 100us .
bcf GPIO,5 ; Clear trigger.
goto hold
up ;---------------- Going up routine -----------------------------
movlw d'40' ; total delay 40+5= 4.5ms.
movwf count4 ;
loop
movlw d'15' ;15 times loop ,8.26msX15=0.123s
movwf count5 ;
zcd
btfsc GPIO,2 ; Zero Voltage crossing yet ?
goto H_1 ; H cycle.
goto L_1 ; L cycle.
H_1
btfsc GPIO,2 ; Zero Voltage crossing yet ?
goto H_1 ;
goto triac_1 ;
L_1
btfss GPIO,2 ; Zero Voltage crossing yet ?
goto L_1 ;
goto triac_1 ;
triac_1
movlw d'5' ; Min delay 500us.
addwf count4,w ; add 45+5=50=5ms.
movwf count3 ; put in counter3
call step_up ;
bsf GPIO,5 ; set GP5 to triger Triac.
call dly_100us ; set triger width =100us.
bcf GPIO,5 ; Clear triger
decfsz count5,f ; loop counter for persistence of vision.
goto zcd ;
decfsz count4,f ;
goto loop ;
goto pw_100 ;
pw_100
btfsc GPIO,3 ; Hold on 10S or 30S.
goto next
goto hold_10s ;
next
btfsc GPIO,1 ; Hold on 30S or 60S
goto hold_30s
goto hold_60s ;
hold_10s
movlw d'12' ; 12 times loop. N=40
movwf count1
goto wait
hold_30s
movlw d'40' ; 40 times loop. N=80
movwf count1
goto wait
hold_60s
movlw d'160' ; 160 times loop. N=250

movwf count1
goto wait
wait
movlw d'100' ; 100 times loop.
movwf count2
wait_1
btfsc GPIO,2 ; Zero Voltage crossing yet ?
goto H_2 ; H cycle.
goto L_2 ; L cycle.
H_2
btfsc GPIO,2 ; Zero Voltage crossing yet ?
goto H_2 ;
goto triac_2 ;
L_2
btfss GPIO,2 ; Zero Voltage crossing yet ?
goto L_2 ;
goto triac_2 ;
triac_2
call dly_100us
call dly_100us
call dly_100us
call dly_100us ; Total delay for 400us.
bsf GPIO,5 ; set GP5 to trigger Triac.
call dly_100us ; set trigger width = 0.1ms.
bcf GPIO,5 ;
decfsz count2,f ;
goto wait_1 ; 100 times loop = 8.26msX100=0.826s.
decfsz count1,f ; yes.
goto wait ; N times loop = 0.826s X N = N sec.
btfsc GPIO,4 ; Has PIR still there.
goto down ; no
goto pw_100 ; yes
down ;-------------------- Going down routine ------------------------------
movlw d'40'
movwf count4 ;
loop_1
movlw d'15' ;
movwf count5 ;
zcd_1
btfsc GPIO,2 ; Zero Voltage crossing yet ?
goto H_3 ; H cycle.
goto L_3 ; L cycle.
H_3
btfsc GPIO,2 ; Zero Voltage crossing yet ?
goto H_3 ;
goto triac_3 ;
L_3
btfss GPIO,2 ; Zero Voltage crossing yet ?
goto L_3 ;
goto triac_3 ;
triac_3
movlw d'210' ;
addwf count4,w ;
movwf count3 ;
call step_down ;
bsf GPIO,5 ; set GP5 to trigger Triac.
call dly_100us ;
bcf GPIO,5 ;
decfsz count5,f ;
goto zcd_1 ;
decfsz count4,f ;
goto loop_1 ;
goto init ;
end